1 files changed, 65 insertions, 0 deletions

diff --git a/gui-wm/labwc/labwc-9999.ebuild b/gui-wm/labwc/labwc-9999.ebuild
new file mode 100644
index 0000000..d5f2f10
--- /dev/null
+++ b/gui-wm/labwc/labwc-9999.ebuild
@@ -0,0 +1,65 @@
+EAPI=8
+
+inherit meson xdg-utils
+
+DESCRIPTION="Openbox alternative for wayland"
+HOMEPAGE="https://github.com/labwc/labwc"
+
+if [[ ${PV} == 9999 ]]; then
+        inherit git-r3
+        EGIT_REPO_URI="https://github.com/labwc/labwc"
+else
+        SRC_URI="https://github.com/labwc/labwc/archive/${PV}.tar.gz -> ${P}.tar.gz"
+        KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+nls +svg +X +icon"
+
+RDEPEND="
+        gui-libs/wlroots:0.19[X?]
+        >=dev-libs/libinput-1.14
+        x11-libs/libxkbcommon:=[X?]
+        dev-libs/libxml2:2
+        x11-libs/cairo[X?]
+        x11-libs/pango[X?]
+        dev-libs/glib:2
+        media-libs/libpng
+        x11-libs/pixman
+        x11-libs/libdrm
+        svg? ( >=gnome-base/librsvg-2.46 )
+        X? ( x11-libs/libxcb:0= >=x11-base/xwayland-21.1.9 )
+        icon? ( >=dev-libs/libsfdo-1.3 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+        app-text/scdoc
+        >=dev-libs/wayland-protocols-1.39
+        nls? ( sys-devel/gettext )
+        virtual/pkgconfig
+"
+
+PATCHES=(
+        "${FILESDIR}/${PN}-0001-meson_doc_path.patch"
+        "${FILESDIR}/${PN}-0002-title-padding.patch"
+)
+
+src_configure() {
+        local emesonargs=(
+                $(meson_feature X xwayland)
+                $(meson_feature nls)
+                $(meson_feature svg)
+                $(meson_feature icon)
+                -Dman-pages=enabled
+        )
+        meson_src_configure
+}
+
+pkg_postinst() {
+        xdg_icon_cache_update
+}
+
+pkg_postrm() {
+        xdg_icon_cache_update
+}