From 9aa7e10df19befcdfe9e55dd9fe0f1d18a729fa9 Mon Sep 17 00:00:00 2001
From: Orfeas <38209077+0xfea5@users.noreply.github.com>
Date: Thu, 18 Sep 2025 17:03:32 +0300
Subject: gui-wm/labwc: add 0.9.1

---
 gui-wm/labwc/Manifest           |  1 +
 gui-wm/labwc/labwc-0.9.1.ebuild | 65 +++++++++++++++++++++++++++++++++++++++++
 gui-wm/labwc/metadata.xml       | 11 +++++++
 3 files changed, 77 insertions(+)
 create mode 100644 gui-wm/labwc/Manifest
 create mode 100644 gui-wm/labwc/labwc-0.9.1.ebuild
 create mode 100644 gui-wm/labwc/metadata.xml

(limited to 'gui-wm')

diff --git a/gui-wm/labwc/Manifest b/gui-wm/labwc/Manifest
new file mode 100644
index 0000000..ba5f57d
--- /dev/null
+++ b/gui-wm/labwc/Manifest
@@ -0,0 +1 @@
+DIST labwc-0.9.1.tar.gz 509342 BLAKE2B 5ca1c1fd1d1b97a5a9cf9ae62cd25b6ac936904fbf641aac12deb2ec8a64ed29146a87c7c4492b69ef81f91c55a0c783c413abd4ef7cc00943e6b8ded212412a SHA512 27bc19e4106cba1ee40e9a8ded12f2f60ba4482c67d1e7fe550d30f68b233970079f6858d3b25ea7d5d1b3fc436269be3d5de44c725fe7f18c88b559babd8ec8
diff --git a/gui-wm/labwc/labwc-0.9.1.ebuild b/gui-wm/labwc/labwc-0.9.1.ebuild
new file mode 100644
index 0000000..354db2b
--- /dev/null
+++ b/gui-wm/labwc/labwc-0.9.1.ebuild
@@ -0,0 +1,65 @@
+EAPI=8
+
+inherit meson xdg-utils
+
+DESCRIPTION="Openbox alternative for wayland"
+HOMEPAGE="https://github.com/labwc/labwc"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/labwc/labwc"
+else
+	SRC_URI="https://github.com/labwc/labwc/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="+nls +svg +X +icon"
+
+RDEPEND="
+	gui-libs/wlroots:0.19[X?]
+	>=dev-libs/libinput-1.14
+	x11-libs/libxkbcommon:=[X?]
+	dev-libs/libxml2:2
+	x11-libs/cairo[X?]
+	x11-libs/pango[X?]
+	dev-libs/glib:2
+	media-libs/libpng
+	x11-libs/pixman
+	x11-libs/libdrm
+	svg? ( >=gnome-base/librsvg-2.46 )
+	X? ( x11-libs/libxcb:0= >=x11-base/xwayland-21.1.9 )
+	icon? ( >=dev-libs/libsfdo-0.1.3 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-text/scdoc
+	>=dev-libs/wayland-protocols-1.39
+	nls? ( sys-devel/gettext )
+	virtual/pkgconfig
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0001-meson_doc_path.patch"
+	"${FILESDIR}/${PN}-0002-title-padding.patch"
+)
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature X xwayland)
+		$(meson_feature nls)
+		$(meson_feature svg)
+		$(meson_feature icon)
+		-Dman-pages=enabled
+	)
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}
diff --git a/gui-wm/labwc/metadata.xml b/gui-wm/labwc/metadata.xml
new file mode 100644
index 0000000..87a5db0
--- /dev/null
+++ b/gui-wm/labwc/metadata.xml
@@ -0,0 +1,11 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<pkgmetadata>
+  <use>
+    <flag name="icon">
+      Enable Labwc support for displaying top level icons in SSD.
+    </flag>
+  </use>
+  <upstream>
+    <remote-id type="github">labwc/labwc</remote-id>
+  </upstream>
+</pkgmetadata>
-- 
cgit v1.2.3