xfce-base/xfdesktop: add xfdesktop-4.20.1 version

2 files changed, 71 insertions, 0 deletions

diff --git a/xfce-base/xfdesktop/Manifest b/xfce-base/xfdesktop/Manifest
new file mode 100644
index 0000000..356b31f
--- /dev/null
+++ b/xfce-base/xfdesktop/Manifest
@@ -0,0 +1 @@
+DIST xfdesktop-4.20.1.tar.bz2 2527982 BLAKE2B b9ce68433181221c20b15bab27d1652ef044b0a1524d9acfbff12b40034f629af8b99eebb6b8874816cc37f4db4874ceca03eec51c7cf091795f0b934d3fd20b SHA512 11f422e31fb5b4f789ac61252a79ef9b139fd0a3e29f1346d5e3c06779567f1809fd78d751df5595cdb5510d0349e908276e85f6325b8ac90dfd00c79ca5d0e2
diff --git a/xfce-base/xfdesktop/xfdesktop-4.20.1.ebuild b/xfce-base/xfdesktop/xfdesktop-4.20.1.ebuild
new file mode 100644
index 0000000..cfecdd1
--- /dev/null
+++ b/xfce-base/xfdesktop/xfdesktop-4.20.1.ebuild
@@ -0,0 +1,70 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg-utils
+
+DESCRIPTION="Desktop manager for the Xfce desktop environment"
+HOMEPAGE="
+        https://docs.xfce.org/xfce/xfdesktop/start
+        https://gitlab.xfce.org/xfce/xfdesktop/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
+
+# CC for /usr/share/backgrounds, see backgrounds/README.md
+LICENSE="GPL-2+ CC-BY-SA-4.0"
+SLOT="0"
+KEYWORDS="amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~sparc x86"
+IUSE="libnotify +thunar wayland X"
+REQUIRED_USE="|| ( wayland X )"
+
+DEPEND="
+        >=x11-libs/cairo-1.16
+        >=dev-libs/glib-2.72.0
+        >=x11-libs/gtk+-3.24.0:3[wayland?,X?]
+        >=xfce-base/exo-0.11:=
+        >=xfce-base/garcon-0.6:=
+        >=xfce-base/libxfce4ui-4.18.0:=[X(+)?]
+        >=xfce-base/libxfce4util-4.13:=
+        >=xfce-base/libxfce4windowing-4.19.8:=[X?]
+        >=xfce-base/xfconf-4.19.3:=
+        libnotify? ( >=x11-libs/libnotify-0.7:= )
+        thunar? (
+                >=dev-libs/libyaml-0.2.5:=
+                >=xfce-base/thunar-4.17.10:=
+        )
+        wayland? ( >=gui-libs/gtk-layer-shell-0.7.0 )
+        X? ( >=x11-libs/libX11-1.6.7 )
+"
+RDEPEND="
+        ${DEPEND}
+"
+BDEPEND="
+        dev-libs/glib
+        >=dev-util/gdbus-codegen-2.80.5-r1
+        dev-util/glib-utils
+        >=sys-devel/gettext-0.19.8
+        virtual/pkgconfig
+"
+
+src_configure() {
+        local emesonargs=(
+                $(meson_feature wayland)
+                $(meson_feature X x11)
+                $(meson_use thunar file-icons)
+                $(meson_feature thunar thunarx)
+                $(meson_feature libnotify notifications)
+                -Dtests=false
+        )
+
+        meson_src_configure
+}
+
+pkg_postinst() {
+        xdg_icon_cache_update
+}
+
+pkg_postrm() {
+        xdg_icon_cache_update
+}