blob: cb63940084797092f9667a9d6de99c93476c53ca (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
|
# Copyright 1999-2026 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson xdg-utils
DESCRIPTION="Desktop manager for the Xfce desktop environment"
HOMEPAGE="
https://docs.xfce.org/xfce/xfdesktop/start
https://gitlab.xfce.org/xfce/xfdesktop/
"
SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.bz2"
# CC for /usr/share/backgrounds, see backgrounds/README.md
LICENSE="GPL-2+ CC-BY-SA-4.0"
SLOT="0"
KEYWORDS="amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~sparc x86"
IUSE="libnotify +thunar wayland X"
REQUIRED_USE="|| ( wayland X )"
DEPEND="
>=x11-libs/cairo-1.16
>=dev-libs/glib-2.72.0
>=x11-libs/gtk+-3.24.0:3[wayland?,X?]
>=xfce-base/exo-0.11:=
>=xfce-base/garcon-0.6:=
>=xfce-base/libxfce4ui-4.18.0:=[X(+)?]
>=xfce-base/libxfce4util-4.13:=
>=xfce-base/libxfce4windowing-4.19.8:=[X?]
>=xfce-base/xfconf-4.19.3:=
libnotify? ( >=x11-libs/libnotify-0.7:= )
thunar? (
>=dev-libs/libyaml-0.2.5:=
>=xfce-base/thunar-4.17.10:=
)
wayland? ( >=gui-libs/gtk-layer-shell-0.7.0 )
X? ( >=x11-libs/libX11-1.6.7 )
"
RDEPEND="
${DEPEND}
"
BDEPEND="
dev-libs/glib
>=dev-util/gdbus-codegen-2.80.5-r1
dev-util/glib-utils
>=sys-devel/gettext-0.19.8
virtual/pkgconfig
"
PATCHES=(
"${FILESDIR}/0001-Fix-the-broken-background-picture-setup-on-Wayland.patch"
)
src_prepare() {
default
}
src_configure() {
local emesonargs=(
$(meson_feature wayland)
$(meson_feature X x11)
$(meson_use thunar file-icons)
$(meson_feature thunar thunarx)
$(meson_feature libnotify notifications)
-Dtests=false
)
meson_src_configure
}
pkg_postinst() {
xdg_icon_cache_update
}
pkg_postrm() {
xdg_icon_cache_update
}
|
